#!/bin/sh

/usr/bin/netstat -an | awk ' 
#
# this little awk acript will take the output of a netstat -an command
# and turn it into a histogram of the number of TCP sockets in various
# states. the original author is Rick Jones <raj@cup.hp.com>. Feel free
# to make use of this under the terms of the copyright present in the 
# netperf benchmark as found on ftp.cup.hp.com.
#
# rick jones
#
BEGIN {
	total_sockets = 0;
	maximum       = 0;
	printnum      = 0;
}

function max(hist) {
	for (foo in hist) if (hist[foo] > maximum) maximum = hist[foo];
	return maximum;
}

function print_bar(hashes, maximum) {
	if (maximum <= 60) {
		for(j=0;j<hashes;j++) printf("#");
	}
	else {
		hash_per_number = maximum / 60;
		for(j=0;j<(hashes / hash_per_number);j++) printf("#");
	}
	printf("\n");
}

function print_dash(dashes) {
	for(j=0;j<dashes;j++) printf("-");
	printf("\n")
}

($1 == "tcp") {
		total_sockets += 1;
		socket_hist[$NF] += 1;
	}

END {
    maximum = max(socket_hist);
    for (state in socket_hist) {
	printf("%11s %6d ",state, socket_hist[state]);
	print_bar(socket_hist[state],maximum);
    }
    print_dash(79);
    printf("%11s %6d\n","TOTAL",total_sockets);
} '